Em Fases de execução de um algoritmo, foi mencionado que um algoritmo possui entrada de dados, processamento e saída de dados como mostrado na figura abaixo.

Fig. 1: Fases de execução

Nessa parte do tutorial, vamos aprender a interagir com o usuário obtendo informações digitadas no teclado e também como exibí-las na saída padrão.

Para capturar o que é digitado pelo usuário, fazemos uso de uma instrução de entrada de dados, chamada leia:

Sintaxe

leia(nome_variavel)

Onde

valor: variável

Quando o usuário digitar um valor, esse será atribuído a variável cujo nome é passado como argumento. Quando leia é executada, o programa ficará suspenso até que o usuário digite um valor e aperte enter para continuar.

Exemplo 1

programa 
{ 
    funcao inicio()  
    {
        cadeia nome 
        inteiro numero
        leia(nome)
        leia(numero)
        escreva(nome)
        escreva("\n") //quebra de linha
        escreva(numero)
    }
}

Saída

fulano
100

Uma entrada de dados pode ser um arquivo, ou algum outro dispositivo conectado ao computador, mas apenas a entrada de dados padrão, teclado, será utilizada nas próximas seções do tutorial.

Para que um possamos ter conhecimento do resultado de um algoritmo, é necessário utilizar alguma forma visual para a exibição de informações na tela do computador. Para isso, vamos utilizar a função de saída de dado: escreva.

Sintaxe

escreve(valor)

Onde

valor: variável, constante, caracter ou texto.

Informamos para a função escreva, como argumento, o que queremos exibir um dado ou resultado de algum algoritmo para o usuário de nosso programa.

Exemplo 2

programa 
{ 
    funcao inicio()  
    {
        real media 
        media = 6.5
        escreva(media)
    }
}

Saída

6.5

Muitas vezes, precisamos informar os resultados de um programa em uma forma mais amigável para o usuário que está utilizando. Tendo isso em mente, utilizamos a função escreva para a exibição formatadas.

Sintaxe

escreva("texto",variavel1)
escreva("texto1","textoN")
escreva("texto",variavel1,"texto",variavelN)

Quebra de linha

escreva("\n")

Tabulação

escreva("\t")

Exemplo 3

programa 
{ 
    funcao inicio()  
    {
        real media
        cadeia 	nome
        media = 10
        nome = "Fulano"
        escreva("Impressão de médias \n")
        escreva("A média do aluno ", nome ," é ",media)
    }
}

Saída

Impressão de médias 
A média do aluno Fulano é 10

A exibição das informações na tela do computador é feita de acordo com a necessidade do problema para qual o algoritmo foi feito e da criatividade de quem necessita da informação.

1. 02/10/2024 - revisão 2 - Ajustes pontuais
2. 29/09/2023 - revisão 1 - Correção em navegação, erros gramaticais, adição de imagem de E/S
3. 08/05/2023 - versão inicial